mirror of
https://git.eden-emu.dev/eden-emu/eden.git
synced 2026-09-10 14:07:25 +00:00
CamilleLaVey
ed566919f4
Very self-explanatory; implementation of the feature for post-processing shaders for Android (at least for now); will allow users to enhance the graphic quality of video games based on the use of multiple shaders adjustable, presets and more, inspired on the PPSSPP implementation, this feature adds 22 customizable shaders (1 pass) that lives on the overlay of the screen, which means that aside of the capability to chain multiple shaders on the screen, this doesn't have depths (pixel/ depth z-buffer) so it ensures the performance with it's use. Few shaders were a faithful port from PPSSPP with their respective attribution on the shader headers for their respective owners; and there are adaptations from public references/ cinematographic (Anime4K) and the rest are my own addition. _Special Credits:_ 1.- PPSSPP Team for their contribution on the public references for shaders: Henrik Rydgard, ShadX, SimoneT, KillaMaaki and guest(r). 2.- Niklas Haas. 3.- bloc97. Reviewed-on: https://git.eden-emu.dev/eden-emu/eden/pulls/4348 Reviewed-by: lizzie <lizzie@eden-emu.dev> Reviewed-by: Maufeat <sahyno1996@gmail.com>
71 lines
2.1 KiB
HLSL
71 lines
2.1 KiB
HLSL
// SPDX-FileCopyrightText: Copyright 2026 Eden Emulator Project
|
|
// SPDX-License-Identifier: GPL-3.0-or-later
|
|
|
|
// SPDX-FileCopyrightText: Copyright 2012 PPSSPP Project
|
|
// SPDX-License-Identifier: GPL-2.0-or-later
|
|
// Ported from bloomnoblur.fsh in PPSSPP.
|
|
|
|
texture BackBufferTex : COLOR;
|
|
sampler BackBuffer { Texture = BackBufferTex; };
|
|
|
|
uniform float Radius <
|
|
ui_type = "slider";
|
|
ui_label = "Radius";
|
|
ui_tooltip = "How far the glow spreads from bright areas.";
|
|
ui_min = 0.0; ui_max = 4.0; ui_step = 0.05;
|
|
> = 1.0;
|
|
|
|
uniform float Amount <
|
|
ui_type = "slider";
|
|
ui_label = "Amount";
|
|
ui_tooltip = "Strength of the glow added on top of the image.";
|
|
ui_min = 0.0; ui_max = 2.0; ui_step = 0.05;
|
|
> = 0.6;
|
|
|
|
void VS_PostProcess(in uint id : SV_VertexID, out float4 pos : SV_Position, out float2 uv : TEXCOORD)
|
|
{
|
|
uv = float2(float(id & 2), float((id & 1) << 1));
|
|
pos = float4(uv * float2(2.0, -2.0) + float2(-1.0, 1.0), 0.0, 1.0);
|
|
}
|
|
|
|
float Weight(float3 color)
|
|
{
|
|
float gray = (color.r + color.g + color.b) / 3.0;
|
|
float saturation = (abs(color.r - gray) + abs(color.g - gray) + abs(color.b - gray)) / 3.0;
|
|
return gray * gray / max(saturation, 0.25);
|
|
}
|
|
|
|
float4 PS_Bloom(float4 pos : SV_Position, float2 uv : TEXCOORD) : SV_Target
|
|
{
|
|
float3 color = tex2D(BackBuffer, uv).rgb;
|
|
|
|
float gray = (color.r + color.g + color.b) / 3.0;
|
|
float saturation = (abs(color.r - gray) + abs(color.g - gray) + abs(color.b - gray)) / 3.0;
|
|
float spread = 0.002 * gray / max(saturation, 0.25) * Radius;
|
|
|
|
float3 sum = float3(0.0, 0.0, 0.0);
|
|
[unroll] for (int x = -3; x <= 3; x += 2)
|
|
{
|
|
[unroll] for (int y = -3; y <= 3; y += 2)
|
|
{
|
|
float3 tap = tex2D(BackBuffer, uv + float2(x, y) * spread).rgb;
|
|
sum += tap * Weight(tap);
|
|
}
|
|
}
|
|
sum /= 16.0;
|
|
|
|
return float4(saturate(color + sum * Amount), 1.0);
|
|
}
|
|
|
|
technique Bloom <
|
|
ui_label = "Bloom";
|
|
ui_tooltip = "Bleeds light out of the brightest areas into a soft halo, the way a camera does when pointed at something too bright.";
|
|
>
|
|
{
|
|
pass
|
|
{
|
|
VertexShader = VS_PostProcess;
|
|
PixelShader = PS_Bloom;
|
|
}
|
|
}
|