mirror of
https://git.eden-emu.dev/eden-emu/eden.git
synced 2026-09-10 22:16:11 +00:00
CamilleLaVey
ed566919f4
Very self-explanatory; implementation of the feature for post-processing shaders for Android (at least for now); will allow users to enhance the graphic quality of video games based on the use of multiple shaders adjustable, presets and more, inspired on the PPSSPP implementation, this feature adds 22 customizable shaders (1 pass) that lives on the overlay of the screen, which means that aside of the capability to chain multiple shaders on the screen, this doesn't have depths (pixel/ depth z-buffer) so it ensures the performance with it's use. Few shaders were a faithful port from PPSSPP with their respective attribution on the shader headers for their respective owners; and there are adaptations from public references/ cinematographic (Anime4K) and the rest are my own addition. _Special Credits:_ 1.- PPSSPP Team for their contribution on the public references for shaders: Henrik Rydgard, ShadX, SimoneT, KillaMaaki and guest(r). 2.- Niklas Haas. 3.- bloc97. Reviewed-on: https://git.eden-emu.dev/eden-emu/eden/pulls/4348 Reviewed-by: lizzie <lizzie@eden-emu.dev> Reviewed-by: Maufeat <sahyno1996@gmail.com>
91 lines
2.9 KiB
HLSL
91 lines
2.9 KiB
HLSL
// SPDX-FileCopyrightText: Copyright 2026 Eden Emulator Project
|
|
// SPDX-License-Identifier: GPL-3.0-or-later
|
|
|
|
texture BackBufferTex : COLOR;
|
|
sampler BackBuffer { Texture = BackBufferTex; };
|
|
|
|
uniform float Timer < source = "timer"; > = 0.0;
|
|
|
|
uniform float Horizon <
|
|
ui_type = "slider";
|
|
ui_label = "Reflection Line";
|
|
ui_tooltip = "Height on screen where the reflective floor begins. Everything above it is left untouched.";
|
|
ui_min = 0.0; ui_max = 1.0; ui_step = 0.01;
|
|
> = 0.55;
|
|
|
|
uniform float Amount <
|
|
ui_type = "slider";
|
|
ui_label = "Amount";
|
|
ui_tooltip = "How strongly the reflection shows through the floor.";
|
|
ui_min = 0.0; ui_max = 1.0; ui_step = 0.05;
|
|
> = 0.35;
|
|
|
|
uniform float Falloff <
|
|
ui_type = "slider";
|
|
ui_label = "Falloff";
|
|
ui_tooltip = "How quickly the reflection fades as the floor comes towards the viewer. At zero it stays even.";
|
|
ui_min = 0.0; ui_max = 4.0; ui_step = 0.1;
|
|
> = 1.2;
|
|
|
|
uniform float Perspective <
|
|
ui_type = "slider";
|
|
ui_label = "Perspective";
|
|
ui_tooltip = "Stretches or squashes the mirrored image. One is a true mirror, higher values pull it towards the line.";
|
|
ui_min = 0.2; ui_max = 2.0; ui_step = 0.05;
|
|
> = 1.0;
|
|
|
|
uniform float Ripple <
|
|
ui_type = "slider";
|
|
ui_label = "Ripple";
|
|
ui_tooltip = "Amplitude of the waves disturbing the reflection. At zero the mirror is perfectly still.";
|
|
ui_min = 0.0; ui_max = 1.0; ui_step = 0.05;
|
|
> = 0.0;
|
|
|
|
uniform float RippleSpeed <
|
|
ui_type = "slider";
|
|
ui_label = "Ripple Speed";
|
|
ui_tooltip = "How fast the waves travel.";
|
|
ui_min = 0.0; ui_max = 4.0; ui_step = 0.1;
|
|
> = 1.0;
|
|
|
|
void VS_PostProcess(in uint id : SV_VertexID, out float4 pos : SV_Position, out float2 uv : TEXCOORD)
|
|
{
|
|
uv = float2(float(id & 2), float((id & 1) << 1));
|
|
pos = float4(uv * float2(2.0, -2.0) + float2(-1.0, 1.0), 0.0, 1.0);
|
|
}
|
|
|
|
float4 PS_Reflections(float4 pos : SV_Position, float2 uv : TEXCOORD) : SV_Target
|
|
{
|
|
float3 color = tex2D(BackBuffer, uv).rgb;
|
|
|
|
float depth = uv.y - Horizon;
|
|
float on_floor = step(0.0, depth);
|
|
float span = max(1.0 - Horizon, 0.001);
|
|
float distance_down = saturate(depth / span);
|
|
|
|
float seconds = Timer * 0.001;
|
|
float wave = sin(uv.x * 38.0 + seconds * RippleSpeed * 2.0) *
|
|
sin(uv.y * 21.0 - seconds * RippleSpeed * 1.3);
|
|
float2 disturbance = float2(wave * 0.004, wave * 0.002) * Ripple * distance_down;
|
|
|
|
float2 mirrored = float2(uv.x, Horizon - depth * Perspective) + disturbance;
|
|
float3 reflection = tex2D(BackBuffer, saturate(mirrored)).rgb;
|
|
|
|
float fade = pow(max(1.0 - distance_down, 0.0001), Falloff);
|
|
float strength = Amount * fade * on_floor;
|
|
|
|
return float4(lerp(color, reflection, strength), 1.0);
|
|
}
|
|
|
|
technique Reflections <
|
|
ui_label = "Reflections";
|
|
ui_tooltip = "Mirrors the picture into a reflective floor below a line you choose, with optional water ripples.";
|
|
>
|
|
{
|
|
pass
|
|
{
|
|
VertexShader = VS_PostProcess;
|
|
PixelShader = PS_Reflections;
|
|
}
|
|
}
|